Sound.getVolume()

Доступность

Flash Player 5.

Синтаксис

my_sound.getVolume() : Number

Параметры

Нет.

Возвращает

Число.

Описание

Метод; возвращает громкость звука в виде числа от 0 до 100, где 0 соответствует тишине, а 100 — максимальной громкости. По-умолчанию уровень громкости равен 100.

Пример

В следующем примере средствами Drawing API рисуется слайдер. При его перемещении в динамически созданном текстовом поле отображается уровень громкости:

var my_sound:Sound = new Sound();
my_sound.loadSound("song3.mp3", true);

this.createEmptyMovieClip("knob_mc", this.getNextHighestDepth());

knob_mc.left = knob_mc._x;
knob_mc.right = knob_mc.left+100;
knob_mc.top = knob_mc._y;
knob_mc.bottom = knob_mc._y;

knob_mc._x = my_sound.getVolume();

with (knob_mc) {
  lineStyle(0, 0x000000);
  beginFill(0xCCCCCC);
  moveTo(0, 0);
  lineTo(4, 0);
  lineTo(4, 18);
  lineTo(0, 18);
  lineTo(0, 0);
  endFill();
}

knob_mc.createTextField("volume_txt", knob_mc.getNextHighestDepth(), knob_mc._width+4, 0, 30, 22);
knob_mc.volume_txt.text = my_sound.getVolume();

knob_mc.onPress = function() {
  this.startDrag(false, this.left, this.top, this.right, this.bottom);
  this.isDragging = true;
};
knob_mc.onMouseMove = function() {
  if (this.isDragging) {
    this.volume_txt.text = this._x;
  }
}
knob_mc.onRelease = function() {
  this.stopDrag();
  this.isDragging = false;
  my_sound.setVolume(this._x);
  
};

См. также

Sound.setVolume()

Смотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление